【04-21】我闲着没事的时候写的一个利用生成静态页缓存ASP的文件

hyt0000

直接报含就可以，支持无参数，或者是类似?typeid=XX&id=XX的参数，根据需要可修改,另外就是必须要手工先建立个temp目录用来放临时文件
要求服务器支持FS0和SHTML,且客户浏览器必须支持Javascript才可以，服务器要求IIS6.0以上，支持Server.Transfer命令
刚做完，还有许多需要调试的BUG存在
累死了，已知BUG，如果客户浏览器支持JAVAScript ，但安全级别设定为高，则生成静态页过程出错，原因是，第一步判断是否支持脚本的过程，只是判断了支持与否，但没有判断浏览器安全设置，而后面利用表单提交参数是用JavaScript来实现，所以会出错，我正在考虑完美的解决办法。
把文件包含在任何ASP上理论上都可以达到使用静态页缓存的目的。

代码部分

Mak.asp

<%'Powered By Houyantao For Lee Junghyun%>
<!--#include file="inc/md5.asp"-->

<%
    '上面包含用来把文件名MD5，保证不会出现重名
    '设置自动过期
    Response.ExpiresAbsolute = Now() - 1
    Response.Expires = 0
    Response.CacheControl = "no-cache"
Set bc = Server.CreateObject("MSWC.BrowserType")
'判断浏览器是否支持Javascript，是就生成静态页面,否则就直接显示
if (bc.javascript = TRUE) then




'制作html页面开始
If Request.ServerVariables("REQUEST_METHOD")="POST" Then
typeid = Request.Form("typeid")
page = Request.Form("page")
id = Request.Form("id")
FileName = Request.Form("FileName")
Dim FileTemp : FileTemp = "temp/"&Md5(FileName&"+"&typeid&"+"&page&"+"&id)

function getHTTPPage(url)
dim Http
set Http=server.createobject("Microsoft.XMLHTTP")
Http.open "GET",url,false
Http.send()
if Http.readystate<>4 then
exit function
end if
getHTTPPage=bytesToBSTR(Http.responseBody,"GB2312")
set http=nothing
if err.number<>0 then err.Clear
end function

'2、转换乱玛，直接用xmlhttp调用有中文字符的网页得到的将是乱玛，可以通过adodb.stream组件进行转换
Function BytesToBstr(body,Cset)
dim objstream
set objstream = Server.CreateObject("adodb.stream")
objstream.Type = 1
objstream.Mode =3
objstream.Open
objstream.Write body
objstream.Position = 0
objstream.Type = 2
objstream.Charset = Cset
BytesToBstr = objstream.ReadText
objstream.Close
set objstream = nothing
End Function


content = getHTTPPage("http://"&Request.ServerVariables("HTTP_HOST")&FileName&"?typeid="&typeid&"&page="&page&"&id="&id)


set fso = Server.CreateObject("Scripting.FileSystemObject")
set fout = fso.CreateTextFile(server.mappath(""&FileTemp&".html"))
fout.write content
fout.close
set fout=nothing
set fso=nothing
IF Err.Number = 0 Then
'Response.Write "<a href="&FileTemp&".html">FileTemp&".html</a>"
%>
<script>
history.back(1)
</script>
<%
Server.Transfer(""&FileTemp&".html")
Response.End
Else
response.Redirect("./")
Response.End
End IF
Application.Lock
Application(FileTemp) = ""
Application.Unlock

End IF
'制作html页面结束



'跳转部分开始
typeid = Request.QueryString("typeid")
page = Request.QueryString("page")
FileName = Request.ServerVariables("SCRIPT_NAME")
id = Request.QueryString("id")
FileTemp = "temp/"&Md5(FileName&"+"&typeid&"+"&page&"+"&id)

IF Application(FileTemp) <> "Make" Then
Set objfso=Server.Createobject("Scripting.Filesystemobject")
'Response.Write FileTemp&".html"
'Response.End

IF objfso.fileexists(Server.Mappath(FileTemp&".html"))  then
Set fsofile=objfso.getfile(Server.MapPath(FileTemp&".html"))
sfilere=fsofile.DateLastModified '获取文件的修改时间
'Response.Write sfilere
IF Now()-1/(24*12) < sfilere Then
'Response.Write "<a href="&FileTemp&".html">FileTemp&".html</a>"
Server.Transfer(FileTemp&".html")
Response.End
Else
Application.Lock
Application(FileTemp) = "Make"
Application.Unlock
%>
<form action="<%=Request.ServerVariables("SCRIPT_NAME")%>?typeid=<%=Typeid%>&id=<%=id%>&page=<%=Page%>" method="post" name="make">
<input type="hidden" value="<%=FileName%>" name="FileName">
<input type="hidden" value="<%=typeid%>" name="typeid">
<input type="hidden" value="<%=page%>" name="page">
<input type="hidden" value="<%=id%>" name="id">
</form>
        <script language="javascript">
                  make.submit();
        </script>
<%
Response.End
End IF
Else
Application.Lock
Application(FileTemp) = "Make"
Application.Unlock
%>
<form action="<%=Request.ServerVariables("SCRIPT_NAME")%>?typeid=<%=Typeid%>&id=<%=id%>&page=<%=Page%>" method="post" name="make">
<input type="hidden" value="<%=FileName%>" name="FileName">
<input type="hidden" value="<%=typeid%>" name="typeid">
<input type="hidden" value="<%=page%>" name="page">
<input type="hidden" value="<%=id%>" name="id">
</form>
        <p>
  <script language="javascript">
                  make.submit();
        </script>
  
<%
Response.End
End IF
'跳转处理部分
End IF
Application.Lock
Application(FileTemp) = ""
Application.Unlock



End IF
%>
2006-6-30 侯延涛 Ctrl

[ 本帖最后由 hyt0000 于 2007-4-21 21:50 编辑 ]

hyt0000

md5.asp
<%
Private Const BITS_TO_A_BYTE = 8
Private Const BYTES_TO_A_WORD = 4
Private Const BITS_TO_A_WORD = 32
Private m_lOnBits(30)
Private m_l2Power(30)
Private Function LShift(lValue, iShiftBits)
    If iShiftBits = 0 Then
        LShift = lValue
        Exit Function
    ElseIf iShiftBits = 31 Then
        If lValue And 1 Then
            LShift = &H80000000
        Else
            LShift = 0
        End If
        Exit Function
    ElseIf iShiftBits < 0 Or iShiftBits > 31 Then
        Err.Raise 6
    End If
    If (lValue And m_l2Power(31 - iShiftBits)) Then
        LShift = ((lValue And m_lOnBits(31 - (iShiftBits + 1))) * m_l2Power(iShiftBits)) Or &H80000000
    Else
        LShift = ((lValue And m_lOnBits(31 - iShiftBits)) * m_l2Power(iShiftBits))
    End If
End Function
Private Function RShift(lValue, iShiftBits)
    If iShiftBits = 0 Then
        RShift = lValue
        Exit Function
    ElseIf iShiftBits = 31 Then
        If lValue And &H80000000 Then
            RShift = 1
        Else
            RShift = 0
        End If
        Exit Function
    ElseIf iShiftBits < 0 Or iShiftBits > 31 Then
        Err.Raise 6
    End If
    RShift = (lValue And &H7FFFFFFE) \ m_l2Power(iShiftBits)
    If (lValue And &H80000000) Then
        RShift = (RShift Or (&H40000000 \ m_l2Power(iShiftBits - 1)))
    End If
End Function
Private Function RotateLeft(lValue, iShiftBits)
    RotateLeft = LShift(lValue, iShiftBits) Or RShift(lValue, (32 - iShiftBits))
End Function
Private Function AddUnsigned(lX, lY)
    Dim lX4
    Dim lY4
    Dim lX8
    Dim lY8
    Dim lResult
     lX8 = lX And &H80000000
    lY8 = lY And &H80000000
    lX4 = lX And &H40000000
    lY4 = lY And &H40000000
    lResult = (lX And &H3FFFFFFF) + (lY And &H3FFFFFFF)
    If lX4 And lY4 Then
        lResult = lResult Xor &H80000000 Xor lX8 Xor lY8
    ElseIf lX4 Or lY4 Then
        If lResult And &H40000000 Then
            lResult = lResult Xor &HC0000000 Xor lX8 Xor lY8
        Else
            lResult = lResult Xor &H40000000 Xor lX8 Xor lY8
        End If
    Else
        lResult = lResult Xor lX8 Xor lY8
    End If
    AddUnsigned = lResult
End Function
Private Function md5_F(x, y, z)
    md5_F = (x And y) Or ((Not x) And z)
End Function
Private Function md5_G(x, y, z)
    md5_G = (x And z) Or (y And (Not z))
End Function
Private Function md5_H(x, y, z)
    md5_H = (x Xor y Xor z)
End Function
Private Function md5_I(x, y, z)
    md5_I = (y Xor (x Or (Not z)))
End Function
Private Sub md5_FF(a, b, c, d, x, s, ac)
    a = AddUnsigned(a, AddUnsigned(AddUnsigned(md5_F(b, c, d), x), ac))
    a = RotateLeft(a, s)
    a = AddUnsigned(a, b)
End Sub
Private Sub md5_GG(a, b, c, d, x, s, ac)
    a = AddUnsigned(a, AddUnsigned(AddUnsigned(md5_G(b, c, d), x), ac))
    a = RotateLeft(a, s)
    a = AddUnsigned(a, b)
End Sub
Private Sub md5_HH(a, b, c, d, x, s, ac)
    a = AddUnsigned(a, AddUnsigned(AddUnsigned(md5_H(b, c, d), x), ac))
    a = RotateLeft(a, s)
    a = AddUnsigned(a, b)
End Sub
Private Sub md5_II(a, b, c, d, x, s, ac)
    a = AddUnsigned(a, AddUnsigned(AddUnsigned(md5_I(b, c, d), x), ac))
    a = RotateLeft(a, s)
    a = AddUnsigned(a, b)
End Sub
Private Function ConvertToWordArray(sMessage)
    Dim lMessageLength
    Dim lNumberOfWords
    Dim lWordArray()
    Dim lBytePosition
    Dim lByteCount
    Dim lWordCount
    Const MODULUS_BITS = 512
    Const CONGRUENT_BITS = 448
    lMessageLength = Len(sMessage)
    lNumberOfWords = (((lMessageLength + ((MODULUS_BITS - CONGRUENT_BITS) \ BITS_TO_A_BYTE)) \ (MODULUS_BITS \ BITS_TO_A_BYTE)) + 1) * (MODULUS_BITS \ BITS_TO_A_WORD)
    ReDim lWordArray(lNumberOfWords - 1)
    lBytePosition = 0
    lByteCount = 0
    Do Until lByteCount >= lMessageLength
        lWordCount = lByteCount \ BYTES_TO_A_WORD
        lBytePosition = (lByteCount Mod BYTES_TO_A_WORD) * BITS_TO_A_BYTE
        lWordArray(lWordCount) = lWordArray(lWordCount) Or LShift(Asc(Mid(sMessage, lByteCount + 1, 1)), lBytePosition)
        lByteCount = lByteCount + 1
    Loop
    lWordCount = lByteCount \ BYTES_TO_A_WORD
    lBytePosition = (lByteCount Mod BYTES_TO_A_WORD) * BITS_TO_A_BYTE
    lWordArray(lWordCount) = lWordArray(lWordCount) Or LShift(&H80, lBytePosition)
    lWordArray(lNumberOfWords - 2) = LShift(lMessageLength, 3)
    lWordArray(lNumberOfWords - 1) = RShift(lMessageLength, 29)
    ConvertToWordArray = lWordArray
End Function
Private Function WordToHex(lValue)
    Dim lByte
    Dim lCount
    For lCount = 0 To 3
        lByte = RShift(lValue, lCount * BITS_TO_A_BYTE) And m_lOnBits(BITS_TO_A_BYTE - 1)
        WordToHex = WordToHex & Right("0" & Hex(lByte), 2)
    Next
End Function

hyt0000

Public Function MD5(sMessage)
    m_lOnBits(0) = CLng(1)
    m_lOnBits(1) = CLng(3)
    m_lOnBits(2) = CLng(7)
    m_lOnBits(3) = CLng(15)
    m_lOnBits(4) = CLng(31)
    m_lOnBits(5) = CLng(63)
    m_lOnBits(6) = CLng(127)
    m_lOnBits(7) = CLng(255)
    m_lOnBits(8) = CLng(511)
    m_lOnBits(9) = CLng(1023)
    m_lOnBits(10) = CLng(2047)
    m_lOnBits(11) = CLng(4095)
    m_lOnBits(12) = CLng(8191)
    m_lOnBits(13) = CLng(16383)
    m_lOnBits(14) = CLng(32767)
    m_lOnBits(15) = CLng(65535)
    m_lOnBits(16) = CLng(131071)
    m_lOnBits(17) = CLng(262143)
    m_lOnBits(18) = CLng(524287)
    m_lOnBits(19) = CLng(1048575)
    m_lOnBits(20) = CLng(2097151)
    m_lOnBits(21) = CLng(4194303)
    m_lOnBits(22) = CLng(8388607)
    m_lOnBits(23) = CLng(16777215)
    m_lOnBits(24) = CLng(33554431)
    m_lOnBits(25) = CLng(67108863)
    m_lOnBits(26) = CLng(134217727)
    m_lOnBits(27) = CLng(268435455)
    m_lOnBits(28) = CLng(536870911)
    m_lOnBits(29) = CLng(1073741823)
    m_lOnBits(30) = CLng(2147483647)
    m_l2Power(0) = CLng(1)
    m_l2Power(1) = CLng(2)
    m_l2Power(2) = CLng(4)
    m_l2Power(3) = CLng(8)
    m_l2Power(4) = CLng(16)
    m_l2Power(5) = CLng(32)
    m_l2Power(6) = CLng(64)
    m_l2Power(7) = CLng(128)
    m_l2Power(8) = CLng(256)
    m_l2Power(9) = CLng(512)
    m_l2Power(10) = CLng(1024)
    m_l2Power(11) = CLng(2048)
    m_l2Power(12) = CLng(4096)
    m_l2Power(13) = CLng(8192)
    m_l2Power(14) = CLng(16384)
    m_l2Power(15) = CLng(32768)
    m_l2Power(16) = CLng(65536)
    m_l2Power(17) = CLng(131072)
    m_l2Power(18) = CLng(262144)
    m_l2Power(19) = CLng(524288)
    m_l2Power(20) = CLng(1048576)
    m_l2Power(21) = CLng(2097152)
    m_l2Power(22) = CLng(4194304)
    m_l2Power(23) = CLng(8388608)
    m_l2Power(24) = CLng(16777216)
    m_l2Power(25) = CLng(33554432)
    m_l2Power(26) = CLng(67108864)
    m_l2Power(27) = CLng(134217728)
    m_l2Power(28) = CLng(268435456)
    m_l2Power(29) = CLng(536870912)
    m_l2Power(30) = CLng(1073741824)
    Dim x
    Dim k
    Dim AA
    Dim BB
    Dim CC
    Dim DD
    Dim a
    Dim b
    Dim c
    Dim d
    Const S11 = 7
    Const S12 = 12
    Const S13 = 17
    Const S14 = 22
    Const S21 = 5
    Const S22 = 9
    Const S23 = 14
    Const S24 = 20
    Const S31 = 4
    Const S32 = 11
    Const S33 = 16
    Const S34 = 23
    Const S41 = 6
    Const S42 = 10
    Const S43 = 15
    Const S44 = 21
    x = ConvertToWordArray(sMessage)
    a = &H67452301
    b = &HEFCDAB89
    c = &H98BADCFE
    d = &H10325476
    For k = 0 To UBound(x) Step 16
        AA = a
        BB = b
        CC = c
        DD = d
        md5_FF a, b, c, d, x(k + 0), S11, &HD76AA478
        md5_FF d, a, b, c, x(k + 1), S12, &HE8C7B756
        md5_FF c, d, a, b, x(k + 2), S13, &H242070DB
        md5_FF b, c, d, a, x(k + 3), S14, &HC1BDCEEE
        md5_FF a, b, c, d, x(k + 4), S11, &HF57C0FAF
        md5_FF d, a, b, c, x(k + 5), S12, &H4787C62A
        md5_FF c, d, a, b, x(k + 6), S13, &HA8304613
        md5_FF b, c, d, a, x(k + 7), S14, &HFD469501
        md5_FF a, b, c, d, x(k + 8), S11, &H698098D8
        md5_FF d, a, b, c, x(k + 9), S12, &H8B44F7AF
        md5_FF c, d, a, b, x(k + 10), S13, &HFFFF5BB1
        md5_FF b, c, d, a, x(k + 11), S14, &H895CD7BE
        md5_FF a, b, c, d, x(k + 12), S11, &H6B901122
        md5_FF d, a, b, c, x(k + 13), S12, &HFD987193
        md5_FF c, d, a, b, x(k + 14), S13, &HA679438E
        md5_FF b, c, d, a, x(k + 15), S14, &H49B40821
        md5_GG a, b, c, d, x(k + 1), S21, &HF61E2562
        md5_GG d, a, b, c, x(k + 6), S22, &HC040B340
        md5_GG c, d, a, b, x(k + 11), S23, &H265E5A51
        md5_GG b, c, d, a, x(k + 0), S24, &HE9B6C7AA
        md5_GG a, b, c, d, x(k + 5), S21, &HD62F105D
        md5_GG d, a, b, c, x(k + 10), S22, &H2441453
        md5_GG c, d, a, b, x(k + 15), S23, &HD8A1E681
        md5_GG b, c, d, a, x(k + 4), S24, &HE7D3FBC8
        md5_GG a, b, c, d, x(k + 9), S21, &H21E1CDE6
        md5_GG d, a, b, c, x(k + 14), S22, &HC33707D6
        md5_GG c, d, a, b, x(k + 3), S23, &HF4D50D87
        md5_GG b, c, d, a, x(k + 8), S24, &H455A14ED
        md5_GG a, b, c, d, x(k + 13), S21, &HA9E3E905
        md5_GG d, a, b, c, x(k + 2), S22, &HFCEFA3F8
        md5_GG c, d, a, b, x(k + 7), S23, &H676F02D9
        md5_GG b, c, d, a, x(k + 12), S24, &H8D2A4C8A
        md5_HH a, b, c, d, x(k + 5), S31, &HFFFA3942
        md5_HH d, a, b, c, x(k + 8), S32, &H8771F681
        md5_HH c, d, a, b, x(k + 11), S33, &H6D9D6122
        md5_HH b, c, d, a, x(k + 14), S34, &HFDE5380C
        md5_HH a, b, c, d, x(k + 1), S31, &HA4BEEA44
        md5_HH d, a, b, c, x(k + 4), S32, &H4BDECFA9
        md5_HH c, d, a, b, x(k + 7), S33, &HF6BB4B60
        md5_HH b, c, d, a, x(k + 10), S34, &HBEBFBC70
        md5_HH a, b, c, d, x(k + 13), S31, &H289B7EC6
        md5_HH d, a, b, c, x(k + 0), S32, &HEAA127FA
        md5_HH c, d, a, b, x(k + 3), S33, &HD4EF3085
        md5_HH b, c, d, a, x(k + 6), S34, &H4881D05
        md5_HH a, b, c, d, x(k + 9), S31, &HD9D4D039
        md5_HH d, a, b, c, x(k + 12), S32, &HE6DB99E5
        md5_HH c, d, a, b, x(k + 15), S33, &H1FA27CF8
        md5_HH b, c, d, a, x(k + 2), S34, &HC4AC5665
        md5_II a, b, c, d, x(k + 0), S41, &HF4292244
        md5_II d, a, b, c, x(k + 7), S42, &H432AFF97
        md5_II c, d, a, b, x(k + 14), S43, &HAB9423A7
        md5_II b, c, d, a, x(k + 5), S44, &HFC93A039
        md5_II a, b, c, d, x(k + 12), S41, &H655B59C3
        md5_II d, a, b, c, x(k + 3), S42, &H8F0CCC92
        md5_II c, d, a, b, x(k + 10), S43, &HFFEFF47D
        md5_II b, c, d, a, x(k + 1), S44, &H85845DD1
        md5_II a, b, c, d, x(k + 8), S41, &H6FA87E4F
        md5_II d, a, b, c, x(k + 15), S42, &HFE2CE6E0
        md5_II c, d, a, b, x(k + 6), S43, &HA3014314
        md5_II b, c, d, a, x(k + 13), S44, &H4E0811A1
        md5_II a, b, c, d, x(k + 4), S41, &HF7537E82
        md5_II d, a, b, c, x(k + 11), S42, &HBD3AF235
        md5_II c, d, a, b, x(k + 2), S43, &H2AD7D2BB
        md5_II b, c, d, a, x(k + 9), S44, &HEB86D391

        a = AddUnsigned(a, AA)
        b = AddUnsigned(b, BB)
        c = AddUnsigned(c, CC)
        d = AddUnsigned(d, DD)
    Next
'    MD5 = LCase(WordToHex(a) & WordToHex(b) & WordToHex(c) & WordToHex(d))
    MD5 = LCase(WordToHex(d)& WordToHex(b))
End Function
%>

korben

好东西,顶啊, 可是不会javaweb耶s:14
楼主辛苦了s:34

xinghutheone

楼主没事的时候爱好这个？服了，电脑达人啊！～～～太有才啦！～～～s:14

没有明天

对了

直接将动态ASP文件转化成静态HTML文件，这样的程序你有吗？

korben

关键 想我这样一点不懂的 , 不知道怎么用啊s:21

东贤

好东东  顶一个



穿别人的鞋,让他找去吧~
抢小孩的糖,让他哭去吧~
坐车抢老太太的座,让他站着去吧

hyt0000

原帖由 wqk831 于 2007-4-21 21:54 发表
对了

直接将动态ASP文件转化成静态HTML文件，这样的程序你有吗？

我在注释 '制作html页面开始 到 '制作html页面结束 之间内容是生成静态页的过程
你可以参考以下，也可以放到后台里做手工生成，那样更简单一些。

如果你想要
类似http://www.laomu9.com/这样的效果
因为这要联系具体的后台来处理，所以没有可以直接套用的程序，只能单独开发。
但只要知道怎么生成静态页就很容易了，这个过程比我这个程序还要简单一些。
其原理是利用XMLHTTP读取内容，然后利用FSO写成静态页。
这个程序其实我做的挺烂，去年第一个生成静态页的，也没规整，现在客户空_间里都是页面文件s:11 s:11 ，

就是先按照不生成静态页的做，做完以后再做生成静态页的程序，并修正链接就可以了。

论坛似乎不能传RAR包

[ 本帖最后由 hyt0000 于 2007-4-21 22:33 编辑 ]

维兰

不知是否原创。。不过写的还是不错的~

Boy冰人

电脑奇才啊~不过看不懂~~

hyt0000

原帖由 维兰 于 2007-4-21 23:01 发表
不知是否原创。。不过写的还是不错的~

呵呵，按照程序员惯例，如果不是原创我会著名转载。
这个我去年在BAIDU贴吧帖过一个比较老的，当时用的是跳转，现在改成直接ASP调用静态页，这样就保证了文件名显示还是显示asp，但实际是调静态页，减少数据库访问。
如果做推广的话还是直接打开静态页的比较好。

没有明天

我网站有个主页流量很大，占CPU，想把他搞成静态页

不是利用模版那种

以前我在网上找到种代码，调整好参数，一运行，就可以把指定的ASP文件，生成指定的HTML文件

后来电脑格式化，搞没了。

[ 本帖最后由 wqk831 于 2007-4-22 00:24 编辑 ]

hyt0000

原帖由 wqk831 于 2007-4-22 00:22 发表
我网站有个主页流量很大，占CPU，想把他搞成静态页

不是利用模版那种

以前我在网上找到种代码，调整好参数，一运行，就可以把指定的ASP文件，生成指定的HTML文件

后来电脑格式化，搞没了。

这很容易啊，就是调asp生成成html，就可以了。就是按照我说的，先做好asp页面再考虑生成静态页的。
主要是链接处理起来比较麻烦
如果只是要生成静态页，那就直接用xmlhttp读要生成静态页的文件，然后利用FSO把返回的html写成文件。
利用这个原理还可以做小偷程序。

[ 本帖最后由 hyt0000 于 2007-4-22 20:28 编辑 ]

jwzhang7

大动作  辛苦了 楼住 。。